&JanelaAppComando("dados";"fechar")

&CriarBotao("Mensagem";"mensagem";100) //*
&CriarBotao("Ajustes de tempo";"ajustes de pausa";130) //*
&CriarBotao("Efetuar envio";"enviar";100) //*
&CriarBotaoPopup("Estou com problema";"Vídeo com tutorial, O sistema não está clicando nos locais certos, Preciso falar com um atendente (suporte)";"video_tutorial, problema clique, canal de suporte";180) //*

#campos_config
destinatarios:Lista de destinatários::Um em cada linha. Serão os números (com DDD) ou ID da plataforma de mensagem compatível, 
mensagem, 
caminho_imagem:Caminho da imagem::exemplo: c:\imagens\panfleto.png, 
legenda:Legenda da imagem::Só é usado se houver uma imagem definida, 
esquema:esquema::link da plataforma compatível
cod_pais:Código do país::Adiciona se não existir 
#
&BlocoLer("campos_config";"campos_config")[0] //*
&TextoSubstituir([campos_config]; "*enter*"; ""; "campos_config")[0] //* Especiais: *aspas*, *pontoevirgula*, *enter*, *tab*
[cod_pais] = 55

#campos_pausa
pausa_envio:Pausa entre envios::(em segundos),
pausa_contato:Tempo para contato abrir::Tempo que o sistema vai esperar um contato abrir antes de começar a clicar e colar a mensagem que deve ser enviada,
pausa_operacional:Pausa operacional::Pausas entre ações do ciclo de envio. Use se erros estiverem ocorrendo,
pausa_imagem:Tempo para imagem carregar::Tempo extra para aguardar a imagem carregar após colada. Use se estiverem ocorrendo erros
#
&BlocoLer("campos_pausa";"campos_pausa")[0] //*
&TextoSubstituir([campos_pausa]; "*enter*"; ""; "campos_pausa")[0] //* Especiais: *aspas*, *pontoevirgula*, *enter*, *tab*

//*

&BotaoVisivel("Efetuar envio";"não")
&BotaoVisivel("Ajustes de tempo";"não")
&BotaoPiscar("Mensagem";10)


#video_tutorial
  &ExecutarComando("https://youtu.be/tkq4VADLsJw?si=4H1iY2q0TGPfWwWs")[0]
#

#comprar
  &ExecutarComando("https://www.sisttemas.com.br/product-page/enviador-universal-msg")[0]
#


#problema clique
   &MensagemPergunta("retorno";"Vamos redefir os pontos de clique atualmente configurados. Desse modo, na próxima vez que você usar o sistema, um assistente vai pedir para você indicar os locais corretos que devem ser clicados durante a automação da tarefa. Podemos continuar?")[0]
   &Se([retorno];igual;"sim")
      &AppRedefinirCliques() //* Reseta os pontos de clique salvos
      &Mensagem("Feito.")
   .fimse      
#

#canal de suporte
   &Mensagem("Para falar com um atendente, nosso canal mais prático é o Whatsapp")   
   &ExecutarComando("https://www.linkws.com.br/whatsapp")[0]
#

#mensagem
   &MensagemDica(20514171518614;"Você pode deixar em branco o campo de mensagem que não quiser usar. Dá para enviar apenas uma mensagem texto, uma imagem com ou sem legenda, ou então enviar uma mensagem texto seguida de uma imagem com legenda.")[0]
   &ValorPedirVarios("Configurações"; "[campos_config]")[0]
   &Se([_resultado];=;"OK")
      &BotaoVisivel("Ajustes de tempo";"sim")
      &BotaoVisivel("Efetuar envio";"sim")
      &BotaoPiscar("Ajustes de tempo";6)
   .fimse
#

#ajustes de pausa   
   &ValorPedirVarios("Configurações de pausa"; "[campos_pausa]")[0]
   &Se([_resultado];=;"OK")
      &MensagemDica(20515211303380;"Se algo sair errado, você pode clicar no botão 'Reiniciar' no canto inferior direito da janela. Se um ponto de clique foi definiro errado ou não está funcionando, você pode usar o menu Utilitários / Redefinir pontos de clique")[0]
      &BotaoVisivel("Efetuar envio";"sim")
      &BotaoPiscar("Efetuar envio";6)
   .fimse
#

#enviar
   &JanelaAppComando("log";"abrir")
   [teste] = [mensagem][caminho_imagem]
   &Se([teste];=;"")
      &MensagemErro("Você precisa definir a mensagem e/ou imagem a ser enviada")[0]
      &BotaoPiscar("Mensagem";3)
      &ScriptEncerrar()
   .fimse
   &JanelaAppPosicionarEspecial("log";"total_direita")[0] //* posições: total_esquerda|total_direita|total_topo|total_baixo|topo_esquerda|topo_direita|topo_centro|baixo_esquerda|baixo_direita|baixo_centro|meio_esquerda|meio_direita|meio_centro|centro

   //* destinatarios, mensagem, caminho_imagem, legenda, esquema, pausa_envio, pausa_operacional, pausa_imagem
   &StatusInserir("Iniciando o envio...";"importante")[0] //* cor: erro, sucesso, alerta, preto, cinza, importante
   &TextoQtdLinhas([destinatarios]; "qtd")[0] //*   
   &StatusInserir("Há [qtd] contatos na lista";"preto")[0]
   
   &Mensagem("Antes de começar, verifique se a plataforma de mensagem que você vai usar já está aberta (ex: Telegram, Whatsapp etc.) Clique em OK quando estiver pronto para começar");
   &MensagemDica(20514174933302;"Você verá um ponteiro amarelo grande na tela. Posicione ele no local onde a mensagem será digitada. Essa configuração só é feita na primeira vez que você usa. Se você fizer algo erado, vá no menu utilitários / redefinir pontos de clique")[0]   
   &Repetir([qtd]) //* a variável _indice terá o número do ciclo atual
      [id] = [destinatarios*[i]]
      &Se([cod_pais];#-\#-/;"")
         &TextoDeixarNumeros([id];"id")[0] //* Retorna os números de um texto
         &TextoAdicionarComeco([id]; [cod_pais]; "id")[0] //*
      .fimse   
      &StatusInserir("Contato [id]: ";"cinza")[0]      
      &ExecutarComando([esquema])[3]
      &Pausar([pausa_contato])
      &JanelaAtivaPosicionar(5;5;750;520)[1] //* esquerda, topo, largura, altura      
      &MouseBotaoPrimarioPerguntar(20514175041303;"Posicione o ponteiro grande amarelo no local que deve ser clicado para digitar a mensagem")[0.5] //*
      &MouseNomeCursor(20514175041303;"nome_cursor";"Informe novamente o local onde a mensagem é digitada")[0] //*
      
      [conseguiu] = "não"
      &Repetir(3)
         &MouseNomeCursor(20514175041303;"nome_cursor";"Informe novamente o local onde a mensagem é digitada")[0] //*
         &Se([nome_cursor];igual;"texto")
            [conseguiu] = "sim"            
            &RepetirEncerrar() //*                        
         .senao
            &StatusInserir("aguardando contato abrir ([i])";"alerta")[1] //* cor: erro, sucesso, alerta, preto, cinza, importante   
         .fimse
      .fimrepetir
      
      &Se([conseguiu];=;"sim")
         //* Se tiver uma mensagem de texto
         &Se([mensagem];#-\#-/;"")
            &Pausar([pausa_operacional])
            &DigitarTexto([mensagem];0)[1]
            &DigitarEnter()[2]
            &Pausar([pausa_operacional])            
         .fimse
         
         &Se([caminho_imagem];#-\#-/;"")
            &Pausar([pausa_operacional])
            &MouseBotaoPrimarioPerguntar(20514175041303;"Local da mensagem")[0.5]/*
            //&ColarImagem([caminho_imagem])[3] //*
            &ColarArquivo([caminho_imagem])[0] //*
            &Pausar([pausa_imagem])
            &Se([legenda];#-\#-/;"")
               &MouseBotaoPrimarioPerguntar(20515185819535;"Arraste o ponteiro amarelo para o local da legenda")[0.5] //*
               &DigitarTexto([legenda];0)[1]               
            .fimse                          
            &DigitarEnter()[2]          
            &Pausar([pausa_operacional])                             
         .fimse    
         
         &Pausar([pausa_envio])            
         &DigitarEsc()[1.5]    
         &Pausar([pausa_operacional])      
         &StatusInserirExtra("processado!";"sucesso")[0]                                       
      .senao
         &StatusInserir("A abertura do contato [id] não foi identificada. Indo para o próximo...";"erro")[0]         
      .fimse
   .fimrepetir 
   &Pausar(3)
   &Mensagem("O processamento foi concluído")
#